Implicit Line Continuation جديد في فيجوال بيسك 10

استكمالا لسلسة مقالات الجديد في منصة دوت نت 4.0 سنقوم اليوم بالتطرق لميزة Implicit Line Continuation الجديدة في الفيجوال بيسك 2010.

في الإصدارات السابقة من الفيجوال بيسك دوت نت كان يتطلب منك إذا أردت أن تقسم سطر برمجي طويل أن تستخدم الشرطة السفلية (_) لتقصير هذه الجمل الطويلة وترتيبها في عدة سطور، حيث الفيجوال بيسك يعتمد على السطر الواحد لإنهاء الجملة بعكس السي شارب على سبيل المثال، والتي تتطلب فاصلة منقوطة لتكون نهاية الجملة أو التعبير البرمجي.
في الإصدار الجديد أصبح إمكانك قطع الجمل الطويلة بدون استخدام الشرطة السفلية ويمكن عمل ذلك في الحالات التالية:

1- بعد الفاصلة (,):

Code

Public Function GetUsername(ByVal username As String,
                                        ByVal delimiter As Char,
                                        ByVal position As Integer) As String
     Return username.Split(delimiter)(position)
End Function

2- بعد أو قبل أقواس الدوالة ( ( , ) ) :

Code

Dim username = GetUsername(
            Security.Principal.WindowsIdentity.GetCurrent().Name,
            CChar("\"),
                 1
)

3- بعد أو قبل أقواس المجموعة ( { , } ):

Code

Dim customer = New Customer With {
        .Name = "Terry Adams",
        .Company = "Adventure Works",
        .Email = "[email protected]"
}

4- بعد أو قبل وسوم التعبيرات الضمنية ( <%= , %>):

Code

Dim customerXml = <Customer>
         <Name>
             <%=
                 customer.Name
             %>
        </Name>
        <Email>
            <%=
                 customer.Email
            %>
        </Email>
    </Customer>

5- بعد لصق سلاسل النصوص ( & ) :

Code

cmd.CommandText = "SELECT * FROM Titles JOIN Publishers " &
"ON Publishers.PubId = Titles.PubID " &
"WHERE Publishers.State = ‘CA’"

6- بعد عمليات المساواة:(=, &=, :=, +=, -=, *=, /=, \=, ^=, <<=, >>=) :

Code

Dim fileStream =
My.Computer.FileSystem. OpenTextFileReader(filePath)

7- بعد العمليات الثنائية ( +, -, /, *, Mod, <>, <, >, <=, >=, ^, >>, <<, And, AndAlso, Or, OrElse, Like, Xor ):

Code

Dim memoryInUse = My.Computer.Info.TotalPhysicalMemory +
            My.Computer.Info.TotalVirtualMemory –
            My.Computer.Info.AvailablePhysicalMemory –
            My.Computer.Info.AvailableVirtualMemory

8- بعد المعاملات : (Is , IsNothing)

Code

If TypeOf inStream Is
            IO.FileStream AndAlso
                 inStream IsNot
    Nothing Then
            ReadFile(inStream)
End If

9- بعد علامة أكبر من أو أصغر من في الواصفات ( < , >) :

Code

<
Serializable()
> Public Class Customer
Public Property Name As String
Public Property Company As String
Public Property Email As String
End Class

10- في ال Linq :

Code

Dim vsProcesses = From proc In
Process.GetProcesses
Where proc.MainWindowTitle.Contains("Visual Studio")
Select proc.ProcessName, proc.Id,
proc.MainWindowTitle

11- بعد الكلمة المحجوزة In في For Each :

Code

For Each p In
vsProcesses
Console.WriteLine("{0}" & vbTab & "{1}" & vbTab & "{2}", p.ProcessName, p.Id, p.MainWindowTitle)
Next

12- بعد كلمة From في Collection intializer :

Code

Dim days = New List(Of String) From
{
"Mo", "Tu", "We", "Th", "F", "Sa", "Su
}

ميزة جديدة ، وتقارب بين الفي بي والسي شارب ، وتمكن من تركيب السيفرات بشكل أسرع وأسهل

وفق الله الجميع